da612fe84f
4b5b4eac58examples/deploy-container: fix `sudo` env propagation (Erik Arvstedt)8d476cfeafnix-bitcoin/runAsUserCmd: remove workaround (Erik Arvstedt)00cceca861joinmarket: fix Python packages (Erik Arvstedt)e4b8e14d3aclightning: fix Python packages (Erik Arvstedt)d1ef2a6e1epythonPackages: improve layout (Erik Arvstedt)74c8593407pythonPackages: add indentation (Erik Arvstedt)109dccca27treewide: use `mdDoc` for descriptions (Erik Arvstedt)a9c1995ed9treewide: rename maintainer `earvstedt` -> `erikarvstedt` (Erik Arvstedt)9e456ea3a9shellcheck-services.nix: update to NixOS 22.11 (Erik Arvstedt)77d58162e7test: update to NixOS 22.11 (Erik Arvstedt)142cbcfb37flake: remove 32-bit systems (Erik Arvstedt)c9b1e59f20update to NixOS 22.11 (Erik Arvstedt)62515a5696helper/update-flake: support updating NixOS versions (Erik Arvstedt) Pull request description: ACKs for top commit: jonasnick: ACK4b5b4eac58Tree-SHA512: b6ff443c4c6721dee9e6bf8f068d72c819851d54cb52d3fec64475cd884825063c28a87b2e9d1645617b7d0e7c1d52ee1ccd898f833c720c25f1b07add938cd5
66 lines
1.7 KiB
Nix
66 lines
1.7 KiB
Nix
{ stdenv, lib, fetchurl, python3, nbPython3PackagesJoinmarket }:
|
|
|
|
let
|
|
version = "0.9.8";
|
|
src = fetchurl {
|
|
url = "https://github.com/JoinMarket-Org/joinmarket-clientserver/archive/v${version}.tar.gz";
|
|
sha256 = "1ab4smpyx966iiiip3g11bcslya37qhac1kgkbmsmlsdkpilw9di";
|
|
};
|
|
|
|
runtimePackages = with nbPython3PackagesJoinmarket; [
|
|
joinmarketbase
|
|
joinmarketclient
|
|
joinmarketbitcoin
|
|
joinmarketdaemon
|
|
matplotlib # for ob-watcher
|
|
];
|
|
|
|
pythonEnv = python3.withPackages (_: runtimePackages);
|
|
in
|
|
stdenv.mkDerivation {
|
|
pname = "joinmarket";
|
|
inherit version src;
|
|
|
|
buildInputs = [ pythonEnv ];
|
|
|
|
installPhase = ''
|
|
mkdir -p "$out/bin"
|
|
|
|
# add-utxo.py -> bin/jm-add-utxo
|
|
cpBin() {
|
|
cp "scripts/$1" "$out/bin/jm-''${1%.py}"
|
|
}
|
|
|
|
cp scripts/joinmarketd.py "$out/bin/joinmarketd"
|
|
cpBin add-utxo.py
|
|
cpBin convert_old_wallet.py
|
|
cpBin receive-payjoin.py
|
|
cpBin sendpayment.py
|
|
cpBin sendtomany.py
|
|
cpBin tumbler.py
|
|
cpBin wallet-tool.py
|
|
cpBin yg-privacyenhanced.py
|
|
cpBin genwallet.py
|
|
|
|
chmod +x -R "$out/bin"
|
|
patchShebangs "$out/bin"
|
|
|
|
## ob-watcher
|
|
obw=$out/libexec/joinmarket-ob-watcher
|
|
install -D scripts/obwatch/ob-watcher.py "$obw/ob-watcher"
|
|
patchShebangs "$obw/ob-watcher"
|
|
ln -s "$obw/ob-watcher" "$out/bin/jm-ob-watcher"
|
|
|
|
# These files must be placed in the same dir as ob-watcher
|
|
cp -r scripts/obwatch/{orderbook.html,sybil_attack_calculations.py,vendor} "$obw"
|
|
'';
|
|
|
|
meta = with lib; {
|
|
description = "Bitcoin CoinJoin implementation";
|
|
homepage = "https://github.com/JoinMarket-Org/joinmarket-clientserver";
|
|
license = licenses.gpl3Only;
|
|
maintainers = with maintainers; [ nixbitcoin ];
|
|
platforms = platforms.unix;
|
|
};
|
|
}
|